// FinalAlert2:YR Script file
// Name: FlyingZ Random Ion Storm Script
// Written By: James Zais aka FlyingZ

AskContinue("This script will disable Superweapons for this map");

SetSafeMode("FALSE","------------------------------------------------------------------- Necessary to edit the map -------------------------------------------------------------------");
Is("%SafeMode%","!=","0","%NoSet%");
Message("SafeMode must be disabled for this script to run!", "FlyingZ", "%NoSet%");
Cancel("%NoSet%");

AllowAdd("--------------------------------------------------------------------- Necessary to edit the map ---------------------------------------------------------------------");
Is("%AddAllowed%","=","0","%NoAdd%");
Message("Adding must be allowed for this script to run!", "FlyingZ", "%NoAdd%");
Cancel("%NoAdd%");

SetIniKey("Authorfscript","0","This map has used FlyingZ Random Ion Storm fscript");
SetIniKey("Authorfscript","1","Created by James Zais aka FlyingZ");

SetIniKey("Lighting","IonAmbient","0.650000");
SetIniKey("Lighting","IonRed","0.695000");
SetIniKey("Lighting","IonGreen","0.445000");
SetIniKey("Lighting","IonBlue","0.775000");

SetIniKey("LightningStormSpecial","DisableableFromShell","no");
SetIniKey("GACSPH","TechLevel","11");
SetIniKey("GAWEAT","TechLevel","11");
SetIniKey("NAIRON","TechLevel","11");
SetIniKey("NAMISL","TechLevel","11");
SetIniKey("YAGNTC","TechLevel","11");
SetIniKey("YAPPET","TechLevel","11");

SetIniKey("General","LightningDamage","40");
SetIniKey("General","LightningDeferment","1");
SetIniKey("General","LightningPrintText","false");
SetIniKey("General","LightningCellSpread","180");
SetIniKey("General","LightningStormDuration","2000");
SetIniKey("General","LightningHitDelay","2000");

SetVariable("Y", "%Height%");
SetVariable("X", "%Width%");

SetWaypoint("500", "X", "Y");


AddTrigger("%TriggerID%", "Neutral,<none>,Ion Storm,0,1,1,1,0", "1,51,0,800", "1,102,0,0,0,0,0,0,SG", "FALSE");

AddTag("%newtag1%", "2,Ion Storm,%TriggerID%");

Message("Random Ion Storms Successfully Enabled ", "FlyingZ");